***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Sep 27, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJD16N06A-AU   D   G   S
*****param & model definition***
.model  dmos  nmos( 
+    l = 1e-6		  w = 1e-6			level = 3
+  vto = 2.2		       kp = 23.5)
.model  dds   d( 
+   is = 7.622e-12	  n = 1.098			   rs = 1.731e-2
+   eg = 1.000	     trs1 = 1.000e-3
)
.model  dbody d( 
+   is = 7.622e-12	  n = 1.098			   rs = 1.731e-2
+  cjo = 3.179e-10	  m = 4.076e-2		   vj = 1.000e-1
+   bv = 66	      ibv = 250e-6		 tbv1 = 8.488e-4			tt = 25n
+ trs1 = 6e-4
)          
.model  inter  nmos( 
+  vto = 0			 kp = 10			level = 1)
.model  dgd    d(

+  cjo = 4.052-10		  m = 3.163e-1		   vj = 3.033e-1)
.param 
+  cgs = 1.153e-9	cgd = 4.006e-10
+   rd = 9.999e-3	      ra  = 1.099e-2			  trd = 2.720e-2 
*****function & circuit***
rg	  G  1t   1
cgs	 1t   3   {cgs}   ic = 0
egv	  2t  3   table   {v(1t, S)} 
+((0   , 0   ),
+ (0.5 , 0.5 ), 
+ (1   , 1   ),
+ (1.5 , 1.5 ),
+ (2   , 2   ),
+ (2.5 , 2.5 ),
+ (3 , 3.05),
+ (4.5 , 4.4),
+ (5, 4.4),
+ (6, 4.6),
+ (20  , 5.5),
+ (22  , 5.5))
egt	  1  2t   value = {9.699e-4*limit(v(2t,3),0,5)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd}
dds	  3   4   dds
dbody	  3   D   dbody
ra	  4   2   {ra} 
rs	  3   5   1e-4
ls	  5   S   0.001n 
m1     1t   8   6   6   inter
e1      8   6   4   1t  2
cgd	  7   4   {cgd}   ic = 0
rcgd    7   4   10meg
dgd     6   4   dgd
rdgd    4   6   10meg
m2      7   9  1t  1t   inter
e2      9  1t   4  1t   -2
.ends 
*$
